DOCBOOK-APPS: Re: Newbie Qs: 1.53 Errors and admon Graphics w/PDF

Hi Andy,

the problem with adminition graphics is that FOP doesn't implement
table-layout=auto. One way to solve this is adding a template to your
customization layer. The one I'm using is (you probably need to adapt at least
the column-width to your needs):

  <!-- fop only supports fixed layout of tables -->
  <xsl:template name="graphical.admonition">
    <xsl:variable name="id">
      <xsl:call-template name="object.id"/>
    </xsl:variable>

    <fo:block id="{$id}">
      <fo:table table-layout="fixed">
        <fo:table-column column-number="1" column-width="1.5cm"/>
        <fo:table-column column-number="2" column-width="13.5cm"/>
        <fo:table-body>
          <fo:table-row>
            <fo:table-cell number-rows-spanned="2">
              <fo:block>
                <fo:external-graphic width="auto" height="auto">
                  <xsl:attribute name="src">
                    <xsl:call-template name="admon.graphic"/>
                  </xsl:attribute>
                  <xsl:attribute name="content-width">
                    <xsl:call-template name="admon.graphic.width"/>
                  </xsl:attribute>
                </fo:external-graphic>
              </fo:block>
            </fo:table-cell>
            <fo:table-cell>
              <fo:block>
                <xsl:apply-templates select="." mode="object.title.markup"/>
              </fo:block>
            </fo:table-cell>
          </fo:table-row>
          <fo:table-row>
            <fo:table-cell number-columns-spanned="2">
              <fo:block>
                <xsl:apply-templates/>
              </fo:block>
            </fo:table-cell>
          </fo:table-row>
        </fo:table-body>
      </fo:table>
    </fo:block>
  </xsl:template>

Hope this helps
Martin