RE: [docbook-apps] Label numbering for Titles in Header

> -----Original Message-----
> From: Lillian Sullam 
> 
> In my running header, I include the section titles down to 
> Sect1.  I would like those titles to also include their label 
> numbering.
> 
> Ex.
> 
> 8  Section
> _____________________________
> 
> Text in the body of the page.
> 
> 
> What I would like:
> 
> 8  1.1 Section
> ______________________________
> 
> Text in the body of the page.


The default section marker does not include the section number (label). You
can add the section number by customizing the "section.heading" template
(sections.xsl):

<xsl:template name="section.heading">
  <xsl:param name="level" select="1"/>
  <xsl:param name="marker" select="1"/>
  <xsl:param name="title"/>
  <xsl:param name="marker.title"/>

  <fo:block xsl:use-attribute-sets="section.title.properties">
    <xsl:if test="$marker != 0">
      <fo:marker marker-class-name="section.head.marker">
     
	 <!-- Add section (sect1) number to marker. -->
       <xsl:apply-templates select="ancestor::sect1" mode="label.markup"/>
	 <xsl:text> </xsl:text>
       <xsl:copy-of select="$marker.title"/>
      </fo:marker>
    </xsl:if>

    <xsl:choose>
      <xsl:when test="$level=1">
        <fo:block xsl:use-attribute-sets="section.title.level1.properties">
          <xsl:copy-of select="$title"/>
        </fo:block>
      </xsl:when>
      <xsl:when test="$level=2">
        <fo:block xsl:use-attribute-sets="section.title.level2.properties">
          <xsl:copy-of select="$title"/>
        </fo:block>
      </xsl:when>
      <xsl:when test="$level=3">
        <fo:block xsl:use-attribute-sets="section.title.level3.properties">
          <xsl:copy-of select="$title"/>
        </fo:block>
      </xsl:when>
      <xsl:when test="$level=4">
        <fo:block xsl:use-attribute-sets="section.title.level4.properties">
          <xsl:copy-of select="$title"/>
        </fo:block>
      </xsl:when>
      <xsl:when test="$level=5">
        <fo:block xsl:use-attribute-sets="section.title.level5.properties">
          <xsl:copy-of select="$title"/>
        </fo:block>
      </xsl:when>
      <xsl:otherwise>
        <fo:block xsl:use-attribute-sets="section.title.level6.properties">
          <xsl:copy-of select="$title"/>
        </fo:block>
      </xsl:otherwise>
    </xsl:choose>
  </fo:block>
</xsl:template>


Mauritz